Как и чем скачивать из интернета

Albert_researcher

Модератор
Команда форума
Как то мне потребовалось скачать информацию со многих URL адресов. Для этого я воспользовался программой Wget. Взять дистрибутив можно по ссылке.
Скачаем нужный файл в соотвествии с разрядностью и поместим его предположим в папку wget, туда же поместим текстовый файл со списком адресов для закачки и созданный батник. Результат работы батника поместим в папку D:\stream (ключ -P).

wget.exe -i spisok.txt -P D:\stream


В файле spisok.tхt предположим была ссылка на закачку по https:// и файл не закачался, в этом случае не удается проверить подлинность сертификата. Чтобы обойти это ограничение, добавляем к команде ключ
--no-check-certificate

Рассмотрим для примера закачку популярной утилиты SmartFix (поместим в отдельную папку: SmartFix.bat и wget.exe)

rename SmartFix.exe SmartFix1.exe
wget.exe --no-check-certificate https://smartfix.pro/SmartFix.exe
if not exist SmartFix.exe (rename SmartFix1.exe SmartFix.exe)
del SmartFix1.exe
exit

Для запуска закаченного файла добавим в код строку вместо exit
SmartFix.exe & exit

Казалось бы все просто, а нет. Например существует проблема скачивания и последующего выполнения исполняемых файлов с Яндекс диска, ссылки на файл там не прямые. Здесь с кондачка не получится. Надеюсь, выяснить решение этого вопроса с помощью сведующих в этом деле форумчан.
 
Последнее редактирование:

dimo70

Модератор
Команда форума
Спасибо, полезно ето.
Вот я дополню только что то интересное. Ander_73 посказал, голова он.
Скачка из Yandex диска напрямую через батника с обходом сертификата ;):
set aria2c=bin\aria2c.exe --check-certificate=false
call :getlink "https://yadi.sk/d/T2DBWSIOTJmhsA" url
%aria2c% "%url%" -x3 -s3
exit
:getlink
set "url=https://cloud-api.yandex.net:443/v1/disk/public/resources/download?public_key=%~1"
%aria2c% "%url%" -d %tmp% -o file.bak
for /f tokens^=^4^ delims^=^" %%a in (%tmp%\file.bak) do set "%2=%%a"
del /q %tmp%\file.bak
exit /b
 

Albert_researcher

Модератор
Команда форума
Спасибо, полезно ето.
Вот я дополню только что то интересное. Ander_73 посказал, голова он.
Скачка из Yandex диска напрямую через батника с обходом сертификата ;):
set aria2c=bin\aria2c.exe --check-certificate=false
call :getlink "https://yadi.sk/d/T2DBWSIOTJmhsA" url
%aria2c% "%url%" -x3 -s3
exit
:getlink
set "url=https://cloud-api.yandex.net:443/v1/disk/public/resources/download?public_key=%~1"
%aria2c% "%url%" -d %tmp% -o file.bak
for /f tokens^=^4^ delims^=^" %%a in (%tmp%\file.bak) do set "%2=%%a"
del /q %tmp%\file.bak
exit /b
aria2c - это легкая мультипротокольная и многопоточная консольная утилита загрузки. Утилита должна находиться в папке bin. Дай ссылку где взять эту утилиту. Я утащил из твоей программы. Дополню твое сообщение: если нужно скачать и запустить программу, то в батнике после строки %aria2c% "%url%" -x3 -s3, добавить строчку start "название скачиваемой программы.exe" (без кавычек). Ты классно все сделал.
 
Последнее редактирование:

dimo70

Модератор
Команда форума
Ето не я, ето Ander_73 сделал классно :) Если бы и я мог так писать комманды было бы замечательно... Размечтался. ;)
Ссылка на aria2c - https://github.com/aria2/aria2/releases/download/release-1.34.0/aria2-1.34.0-win-64bit-build1.zip

Тут вот что интересно узнать. Возможно ли по подобию скачки с яндекса сделать скачку с google drive например?
 

dimo70

Модератор
Команда форума
Вчера искал способ скачки с Мега. Оказалось что все очень просто и давно придумано.
Во первых скачиваем megatools. Потом пишем комманд файл:
megatools dl "линк на мега"
Megatools.exe ставим рядом с команд файла.
Ето очень пригодится тем (в том числе и я) где скачка с мега быстрее, чем с яндекс диска. Кроме того мега предоставляет до 50 GB свободного места безплатно.
При помощью комманд файла можно автоматизировать скачку и сделать запуск после скачивания файла, или подключить в другой скрипт.
 

Albert_researcher

Модератор
Команда форума
Мне тоже есть, что рассказать. Вроде получилось.

Создание прямой ссылки на скачивание файла с Диск Google (Google Drive)
Предположим я открыл доступ к файлу и скопировал ссылку для общего доступа.
пример ссылки
выделяем из ссылки id=1dm4o1wYM0nMC-MmRTCsehzbN3IgpdxH5
Подставляем после формы или https://drive.google.com/uc?export=download&confirm=no_antivirus&id= и получаем прямую ссылку на скачивание файла для общего доступа.
id=1dm4o1wYM0nMC-MmRTCsehzbN3IgpdxH5
Затем переименуем полученный файл в требуемый с нужным расширением (текст после https://drive.google.com/)
wget.exe "https://drive.google.com/uc?export=download&id=1dm4o1wYM0nMC-MmRTCsehzbN3IgpdxH5"
rename "uc@export=download&id=1dm4o1wYM0nMC-MmRTCsehzbN3IgpdxH5" 400U.pdf
start 400U.pdf
Разумеется в папке для скачивания кроме батника должен лежать файл wget.exe
 
Последнее редактирование:

Albert_researcher

Модератор
Команда форума
Я не дома. Очень интересно про exe файлы. Напиши о результате.
 

wadimus

Новичок
Во первых скачиваем megatools. Потом пишем комманд файл:
а вот скачать его как? :)
и желательно:
- самую крайнюю версию (это архивы в конце списка)
- скачать автоматом, т.е. запустил батник - и получил рядом два архива (по разрядностям)
- если архивы уже есть - то будут скачиваться только если они изменились на офсайте .
- при прерывании скачивания - хоть что-то осталось (т.н. защита от дурака)
- и выделить версию в файл
- и чтобы конечные файлы (архивы) были нормализованы по названию (т.е. в названиях не было цЫфр версии)

ЗЫ. это я демонстрирую вам свои мозоли, которые я натёр при решении таких вот задач ..
 

wadimus

Новичок
Рассмотрим для примера закачку популярной утилиты SmartFix (поместим в отдельную папку: SmartFix.bat и wget.exe)
это пример решения в лоб.
качается долго, мне надоела скачивание, я прервал - получим крах! или тернет внезапно пропал - получим крах.
если файл уже есть, то зачем его заново качать?
если файл есть, но на офсайте он другой (по размеру) - качать надо, иначе (размер нашего файла и находящегося в тернете одинаковый) - качать не надо.

опишу стратегию (которая ИМХО):
- создаем некий файл - файл неуспешности (туда пишем что-то).
если этот файл останется после нашего скачивания - то процесс скачивания где-то получил проблему.
нет этого файла после скачивания - мы успешно обновили прогу (а возможно и нет, если она такая же по размеру как и в тернете)
- определяем размер нашего файла (если он есть), иначе (файла нет) - размер равен 0
- определяем (без скачивания!) размер файла, находящегося в тернете (по ссылке)
- если эти два числа не совпадают, надо качать, иначе (размеры совпадают) - идем на метку 1
- начинаем качать .. качаем не в готовый файл(!), а в промежуточный(!) - для защиты от прерывания скачивания (или самим надоело и закрыли командное окно или тернет пропал или сайт недоступен)
- скачали промежуточный файл - проверяем его размер, если он равен 0, то докачка неуспешна! идем на метку 2
- продолжаем .. удаляем лежащий рядом файл и переименовываем промежуточный в такой-же (он новее и с другой версией)
- определяем версию нового файла
- метка 1
- удаляем файл неуспеха и временные файлы
- метка 2
- выход

это стратегия .. могу дать шаблон (это батник со многими путями решения)
 
Последнее редактирование:

Albert_researcher

Модератор
Команда форума
это пример решения в лоб.
качается долго, мне надоела скачивание, я прервал - получим крах! или тернет внезапно пропал - получим крах.
если файл уже есть, то зачем его заново качать?
если файл есть, но на офсайте он другой (по размеру) - качать надо, иначе (размер нашего файла и находящегося в тернете одинаковый) - качать не надо.

опишу стратегию (которая ИМХО):
- создаем некий файл - файл неуспешности (туда пишем что-то).
если этот файл останется после нашего скачивания - то процесс скачивания где-то получил проблему.
нет этого файла после скачивания - мы успешно обновили прогу (а возможно и нет, если она такая же по размеру как и в тернете)
- определяем размер нашего файла (если он есть), иначе (файла нет) - размер равен 0
- определяем (без скачивания!) размер файла, находящегося в тернете (по ссылке)
- если эти два числа не совпадают, надо качать, иначе (размеры совпадают) - идем на метку 1
- начинаем качать .. качаем не в готовый файл(!), а в промежуточный(!) - для защиты от прерывания скачивания (или самим надоело и закрыли командное окно или тернет пропал или сайт недоступен)
- скачали промежуточный файл - проверяем его размер, если он равен 0, то докачка неуспешна! идем на метку 2
- продолжаем .. удаляем лежащий рядом файл и переименовываем промежуточный в такой-же (он новее и с другой версией)
- определяем версию нового файла
- метка 1
- удаляем файл неуспеха и временные файлы
- метка 2
- выход

это стратегия .. могу дать шаблон (это батник со многими путями решения)
Если файл уже есть, он будет переименован. Закачается новый файл и переименованный файл удалится. Если закачка будет неуспешной, то переименованный файл обратно будет переименован и с ним будем работать. Меня это устраивает, и проверено в работе. В конечном итоге, это только пример использования утилиты wget. Кстати, поделитесь своим шаблоном, интересно.
 
Последнее редактирование:

Albert_researcher

Модератор
Команда форума
Для скачивания /закачивания папок из /на Google Drive

Для Google Drive есть ссылка на утилиту gdrive
Закачиваем соответственно разрядности:
Код батника
gdrive-windows-386.exe download id-файла --recursive

Примеры
gdrive-windows-x64.exe upload c:\folder\file.zip
Скачиваем:
gdrive-windows-x64.exe download id-файла

При первом запуске gdrive вам будет предложено ввести код подтверждения. Код получается, следуя напечатанному URL-адресу (я скопировал адрес из батника) и пройдите аутентификацию в учетной записи Google на диске, к которому хотите получить доступ (вставьте URL в строку браузера). Это создаст файл токена в папке .gdrive в вашем домашнем каталоге, который нужно скопировать и вставить в батник. Обратите внимание, что любой, у кого есть доступ к этому файлу, также будет иметь доступ к вашему диску Google.
 

wadimus

Новичок
Если файл уже есть, он будет переименован. Закачается новый файл и переименованный файл удалится. Если закачка будет неуспешной, то переименованный файл обратно будет переименован и с ним будем работать.
типичная ошибка ..
запустил батник .. он в терминальном окне .. надоело смотреть, как скачивается, и я его закрыл (нажал на крестик в правом верхнем углу) - и всё! файл недокачался! переименованный файл обратно не переименован.
допустим, файл качается - и мы из вредности выдернули кабель тернета из компа (прекратили скачивание) - сработает тайм-аут. возможно, недокачанный файл останется и он будет в качестве готового.

насчет wget.exe - слабоват он .
для скачивания пользуюсь этим:
axel.exe - много-поточный качатель .. использую его в полную силу, файл качается в 8 потоков (если офсайты поддерживают это)!
ускорение в .. млин .. на ру-борде замерял скачивание больших файлов .. ускорение в 2-4-6 раз!
 

Albert_researcher

Модератор
Команда форума
wadimus спасибо за информацию, надеюсь есть возможность использовать axel.exe в батнике для закачки и дальнейшего запуска программ.
 

wadimus

Новичок
вот мой батничек для скачивания SmartFix
расставил комменты для понимания ..
утилиты для работы находятся в определённой папке \Scripts
этот батничек сделан по шаблону .. таких батничков у меня около .. млин .. скока же .. чуть меньше 1000!
Код:
@echo off
:: узкая полоска в 5 строк
mode con cols=85 lines=5
SetLocal EnableExtensions EnableDelayedExpansion
CD /d "%~dp0"

echo ... SmartFix

:: откуда качаем (источник)
set "g1=https://smartfix.pro/SmartFix.exe"
:: что качаем (конечный файл)
set "w1=SmartFix.exe"

:: создаем файл неуспеха
echo.?> "%~dp0alarm.txt"
:: если есть конечный файл, вычисляем его размер, иначе размер равен 0
:: этот размер пишем в переменную 1
if exist "%~dp0%w1%" ( for %%a in ("%~dp0%w1%") do set "fsize=%%~za" ) else ( set "fsize=0" )
:: вычисляем размер файла, который находится в источнике (не скачивая его)
:: размер пишется во временный файл в одну строку
("%~dp0..\Scripts\netsize.exe" "%g1%") >"%~dp0down.txt"
:: эту строку передаем в переменную 2
Set /p nsize=<"%~dp0down.txt"
:: сравниваем две переменных
:: если они разные - начинаем скачивание
if %fsize% NEQ %nsize% (
:: работает axel.exe
:: качаем в 8 потоков
:: и качаем не сразу в конечный файл, а в промежуточный (SmartFix.exe.~)
"%~dp0..\Scripts\axel.exe" "%g1%" -k -a -n 8 -o "%~dp0%w1%.~"
:: проверяем успешность скачивания
:: определяем размер ппромежуточного файла
for %%a in ("%~dp0%w1%.~") do set size=%%~za
:: если этот размер не равен 0, то скачка успешна
:: иначе - идем на метку 1
:: в этом случае файл неуспеха остается, и остается конечный файл (он старый)
:: даже если мы прервали работу батника - всё останется как и прежде, но будет мусор (недокачанные и временные файлы)
:: их потом можно почистить
if !size!==0 goto 1
:: удаляем существующий конечный файл
del "%~dp0%w1%" /q
:: переименовываем промежуточный в конечный
ren "%~dp0%w1%.~" "%w1%"
:: пишем дату скачивания в файл date.txt
echo %date%> "%~dp0date.txt"
:: вычисляем версию конечного файла
("%~dp0..\Scripts\filever.exe" /A /D "%~dp0%w1%") >"%~dp0down.txt"
FOR /F "usebackq tokens=4" %%a in ("%~dp0down.txt") do set f=%%a
:: и пишем её в файл version.txt
echo %f%> "%~dp0version.txt"
)
:: удаляем файл неуспеха
del "%~dp0alarm.txt" /q
:1
:: удаляем временные файлы
del "%~dp0down.txt" /q
del "%~dp0*.~" /q
:: оставшийся файл неуспеха говорит об том, что скачка потерпела крах,
:: но есть новая версия этого файла, которую можно потом скачать
:: но даже несмотря на это - мы можем пользоваться нужным нам файлом
 

wadimus

Новичок
вот батник для скачивания 2-х архивов с Megatools.exe
архивы (megatools-win32.zip и megatools-win64.zip) берутся самые новые
в файле version.txt в одну строку версия (на данный день строка такая: 1.11.0-git-20190608)

Код:
@echo off
mode con cols=85 lines=5
SetLocal EnableExtensions EnableDelayedExpansion
CD /d "%~dp0"

echo ... Megatools - command line client for Mega.nz

set "h1=https://megatools.megous.com/builds/experimental/"
set "d1=[0-9][.]zip"
set "w1=megatools-win32.zip"
set "w2=megatools-win64.zip"

echo.?> "%~dp0alarm.txt"
("%~dp0..\Scripts\http2cli.exe" "%h1%" 2| findstr /R /C:"%d1%") >"%~dp0down.txt"
for %%a in ("%~dp0down.txt") do set size=%%~za
if %size%==0 goto 1
rem берем 2-е последних строки
for /f %%n in ( 'more ^< "%~dp0down.txt" ^| find /c /v ""' ) do set f=%%n
set /a f-=2
(more +%f% < "%~dp0down.txt") > "%~dp0down1.txt"
<"%~dp0down1.txt" (for /f "tokens=1* delims=[]" %%a in ('find /n /v ""') do set "s%%a=%%b")
FOR /F "tokens=2 delims=+++" %%a in ("%s1%") do set "g1=https://megatools.megous.com/builds/experimental/%%a"
FOR /F "tokens=2 delims=+++" %%a in ("%s2%") do set "g2=https://megatools.megous.com/builds/experimental/%%a"
FOR /F "tokens=2,3,4 delims=-" %%a in ("%s1%") do set "f=%%a-%%b-%%c"
if exist "%~dp0%w1%" ( for %%a in ("%~dp0%w1%") do set "fsize=%%~za" ) else ( set "fsize=0" )
("%~dp0..\Scripts\netsize.exe" "%g1%") >"%~dp0down.txt"
Set /p nsize=<"%~dp0down.txt"
if %fsize% NEQ %nsize% (
"%~dp0..\Scripts\axel.exe" "%g1%" -k -a -n 8 -o "%~dp0%w1%.~"
for %%a in ("%~dp0%w1%.~") do set size=%%~za
if !size!==0 goto 1
del "%~dp0%w1%" /q
ren "%~dp0%w1%.~" "%w1%"
echo %date%> "%~dp0date.txt"
)
if exist "%~dp0%w2%" ( for %%a in ("%~dp0%w2%") do set "fsize=%%~za" ) else ( set "fsize=0" )
("%~dp0..\Scripts\netsize.exe" "%g2%") >"%~dp0down.txt"
Set /p nsize=<"%~dp0down.txt"
if %fsize% NEQ %nsize% (
"%~dp0..\Scripts\axel.exe" "%g2%" -k -a -n 8 -o "%~dp0%w2%.~"
for %%a in ("%~dp0%w2%.~") do set size=%%~za
if !size!==0 goto 1
del "%~dp0%w2%" /q
ren "%~dp0%w2%.~" "%w2%"
echo %date%> "%~dp0date.txt"
)
echo %f%> "%~dp0version.txt"
del "%~dp0alarm.txt" /q
:1
del "%~dp0down.txt" /q
del "%~dp0*.~" /q
del "%~dp0down1.txt" /q
 

Albert_researcher

Модератор
Команда форума
вот мой батничек для скачивания SmartFix
расставил комменты для понимания ..
утилиты для работы находятся в определённой папке \Scripts
этот батничек сделан по шаблону .. таких батничков у меня около .. млин .. скока же .. чуть меньше 1000!
Код:
@echo off
:: узкая полоска в 5 строк
mode con cols=85 lines=5
SetLocal EnableExtensions EnableDelayedExpansion
CD /d "%~dp0"

echo ... SmartFix

:: откуда качаем (источник)
set "g1=https://smartfix.pro/SmartFix.exe"
:: что качаем (конечный файл)
set "w1=SmartFix.exe"

:: создаем файл неуспеха
echo.?> "%~dp0alarm.txt"
:: если есть конечный файл, вычисляем его размер, иначе размер равен 0
:: этот размер пишем в переменную 1
if exist "%~dp0%w1%" ( for %%a in ("%~dp0%w1%") do set "fsize=%%~za" ) else ( set "fsize=0" )
:: вычисляем размер файла, который находится в источнике (не скачивая его)
:: размер пишется во временный файл в одну строку
("%~dp0..\Scripts\netsize.exe" "%g1%") >"%~dp0down.txt"
:: эту строку передаем в переменную 2
Set /p nsize=<"%~dp0down.txt"
:: сравниваем две переменных
:: если они разные - начинаем скачивание
if %fsize% NEQ %nsize% (
:: работает axel.exe
:: качаем в 8 потоков
:: и качаем не сразу в конечный файл, а в промежуточный (SmartFix.exe.~)
"%~dp0..\Scripts\axel.exe" "%g1%" -k -a -n 8 -o "%~dp0%w1%.~"
:: проверяем успешность скачивания
:: определяем размер ппромежуточного файла
for %%a in ("%~dp0%w1%.~") do set size=%%~za
:: если этот размер не равен 0, то скачка успешна
:: иначе - идем на метку 1
:: в этом случае файл неуспеха остается, и остается конечный файл (он старый)
:: даже если мы прервали работу батника - всё останется как и прежде, но будет мусор (недокачанные и временные файлы)
:: их потом можно почистить
if !size!==0 goto 1
:: удаляем существующий конечный файл
del "%~dp0%w1%" /q
:: переименовываем промежуточный в конечный
ren "%~dp0%w1%.~" "%w1%"
:: пишем дату скачивания в файл date.txt
echo %date%> "%~dp0date.txt"
:: вычисляем версию конечного файла
("%~dp0..\Scripts\filever.exe" /A /D "%~dp0%w1%") >"%~dp0down.txt"
FOR /F "usebackq tokens=4" %%a in ("%~dp0down.txt") do set f=%%a
:: и пишем её в файл version.txt
echo %f%> "%~dp0version.txt"
)
:: удаляем файл неуспеха
del "%~dp0alarm.txt" /q
:1
:: удаляем временные файлы
del "%~dp0down.txt" /q
del "%~dp0*.~" /q
:: оставшийся файл неуспеха говорит об том, что скачка потерпела крах,
:: но есть новая версия этого файла, которую можно потом скачать
:: но даже несмотря на это - мы можем пользоваться нужным нам файлом
Благодарю за науку. Надеюсь на Вашу дальнейшую помощь.
 

dimo70

Модератор
Команда форума
wadimus
Ну ты даешь. Спасибо за хорошие батники. Нужно время чтоб изучить все ето. :)
 

wadimus

Новичок
продолжу описание ..
этот сборник - как незавершенная раздача на бабочке.
2 архива распаковать в одну папку
запустить start.exe
нажать кнопку Help
читать

описание (сделал в виде вопросы-ответы)
Название: Opti: Browser-2019

Версия программы: март 2019
Язык интерфейса: Русский

Лечение: не требуется (инсталлятор уже пролечен)
Системные требования: XP,Vista,7,8,8.1,10

Примечание:
Сборка раздаётся в облегченном (из сборки удалены все инсталляторы, даты, версии) в т.н. "высушенном" виде.
Не пугайтесь такого малого размера. По мере обновления (заполнения) сборка на февраль 2019 имеет размер около 9Гб (9.480 Гб).

Особенности:
Все программы разделены по категориям (я называют это каталогизация). Каталогизация у данной сборки модифицирована.
Для каждого пункта имеется описание, которое появляется внизу окна при наведении курсора. Внимательно читайте краткую расшифровку строк.
Данный сборник имеет такую особенность, что система сама определяет какую разрядность архитектуры ставить - x86 (32-bit) или x64 (64-bit).

Описание:
Описание в виде Вопросы-Ответы.
- Что это?
- Это очередной сборник программ для установки и обновления.

- Поподробнее?
- Сборник бессплатных программ узкой направленности (браузеры) с возможностью модификации, перестройки, расширения и конечно же обновления.

- А еще подробнее?
- Сборка двух-фазная. Можно запустить сборку в двух режимах: - режиме обновления и режиме установки. Фаза - это процесс перестройки сборки в такие режимы.

- Почему такой маленький размер?
- Сборник "высушенный" (из него удалены все инсталляторы, все даты, версии) - в нём ничего нет. Он чистый!

- Как это чистый? А как с ним (сборником) работать?
- Вначале сборник надо заполнить. Заполнение его аналогично стадии установки: запустили автоустановщик программ MInstall, пометили галочками нужные строки для обновления и, нажатием кнопки Выполнить, обновили инсталляторы.

- Обновили сборник, что дальше?
- Зависит от вас. Если нужна установка - запустили автоустановщик программ MInstall в режиме установки и установили нужные программы.

- Получается, в сборнике есть несколько способов его использования?
- Да. Стадии (я называют это фазированием) две.
Одна стадия - это обновление,
Вторая стадия - установка. Сборник двухфазный!

- А сколько фаз существует?
- Вообще фаз три:
- Установка программ;
- Обновление обновляемых программ (бессплатных из официальных источников)
- И третья фаза - это обновление необновляемых программ (репаков, переделок). Обновление идет с использованием облаков (яндекс-диск)
Третья фаза пока не афишируется. Она для универсальных сборок.

- В сборнике куча ненужных мне программ, хочу избавиться от них.
- Каждый инсталлятор находится в отдельной папке (кроме инсталлятора в каждой папке также есть много служебных файлов). Совокупность всех таких файлов я называю ячейкой. Каждая ячейка независима от других (связь всё же может быть, логическая и программная). Любую ячейку можно удалить. Также можно модифицировать любую ячейку. Поэтому - не нравится ненужная вам программа - удалите папку, содержащую эту ячейку.

- В списке есть дубли. Зачем?
- Некоторые программы можно получить несколькими способами (используя официальные или неофициальные источники). Какими пользоваться? зависит от вас. Ненужную ячейку просто удалите.

- У меня слабый тернет, хочу обновить инсталляторы. Что делать?
- Каждая ячейка (в ней находятся инсталляторы и служебные файлы) имеет множественную защиту от дурака (ни-в-коем случае не намекаю на техническую грамотность пользователя). Если нет тернета - то ничего не качается, ничего в ячейках не меняется. Каждая ячейка изолирована от других. В ячейке будет идти скачивание (и замена старых инсталляторов новыми скачанными) только тогда, когда размер файлов (находящихся на офсайтах и еще не скачанных нами) будет отличаться от размера файлов, находящихся в ячейке. Т.е. скачивание пойдет только тогда, когда на офсайтах есть новинки. Файлы не изменились - ничего не качается!

Частота появления новинок зависит только от производителей. Скорость скачивания тоже зависит не от нас. Некоторые ячейки обновляются быстро, некоторые до ужжаса медленно. Сами практикуйтесь на таких ячейках. Медленные ячейки можно обновлять не так часто.

- Во время скачивания пропал тернет. Скачивание слишком долгое, сам закрыл окно скачивания. Что делать?
- Защита от дурака сработает и тут. Во-первых, скачивание нужных файлов идет во временные файлы (и никак не затрагивают находящиеся в ячейке старые инсталляторы). Если прекратили скачивание - ячейка помечается как неуспешная, в ней остаётся мусор, но старые файлы остались. Можно продолжать пользование этой ячейкой. Во-вторых, только после успешного скачивания, произойдет замена временных файлов на наши инсталляторы. После чего вычислится версия и изменится дата скачивания. После чего ячейка становится успешной (в ней находятся инсталляторы, обновленные на дату скачивания).

- Не идет обновление. Что делать?
- Тут много причин. Часть из них обьяснил в помощи. Прекратите обновление данной ячейки. Если в ней уже были инсталляторы - пользуйтесь старыми версиями. Можно попробовать обновиться позже. Если обновление совсем не идет - пишите, буду править такие ячейки.

- Установка некоторых программ не идет. Запускается файл и всё.
- Файлы для установки (инсталляторы) делятся на несколько групп:
- автоустанавливаемые (установки таких инсталляторов происходит в автоматическом режиме)
- ручная установка (в ячейках находятся файлы с официальных сайтов, т.н. оригиналы - и некоторые инсталляторы не подразумевают тихую установку их. Такова прихоть разработчиков. Возможно, разработчики используют инсталляторы с неизвестной мне системой тихих ключей для установки) - такие программы необходимо ставить самому, нажимая соотв. кнопки.
- некоторые инсталляторы представляют собой архивы. Запуск такого файла вызовет запуск ассоциированного с архивами архиватора. В этом случае распакуйте содержимое архива в нужное вам место, после чего закройте архив.
- есть ячейки, где инсталлятор - это запускаемый файл (портабельный). Простой запуск такого файла вызовет создание ненужных файлов в этой ячейке. Поэтому такой файл при авто-установке скопируется на Рабочий стол.

- Почему копирование на Рабочий стол?
- Предложите свой способ. Создать определенную папку на диске и копировать туда портабельную программу из ячейки? Пишите.

- Не нравится название, описание, группирование программ. Не нравится мелькание окон. Что делать?
- Меняйте сами. В помощи описал порядок действий.

- Получается, сборник не имеет ограничений в размере, количестве программ?
- Да! Данный сборник (Браузеры) - это мой первый блин, В нём собраты большинство браузеров. И большая часть из них никогда не будет ставиться простым юзером. Убирайте ненужное, не нравится какая-то программа - удалите её!

Надеюсь, в раздаче будут бонусы: ячейки, дополняющие наш сборник. В бонусах постараюсь собрать сборку ячеек другой направленности но для тернет-работы (Online Music Player, Chat (Vk + Ok + FaceBook), Cloud + Steam, Mail, Download, DC-FTP, TV-Radio, Web Camera).

Главное для этого сборника - бессплатность и возможность скачать файлы с официальных сайтов!

Расширение (увеличение номенклатуры) сборника будет таким: нужную ячейку (папку) просто копируете в определенное место и потом перестраиваете сборку.

- Хочу еще, а можно добавить еще программы?
- Пишите. Можно.

- Что еще хотите сказать, написать?
- Сразу признаюсь, сборка браузеров - это некая "шпилька" некоторым релизерам .. - вы создаёте релизы на бессплатные, часто обновляемые программы? - а вот вам такое: получение новинок простым юзерам без проблемм (проблемы это: увидели новый релиз, скачали торрент-файл, запустили его в торрент-клиенте, потом копируете скачанное в нужное место) - и тут запустили сборку, поставили нужную галочку и обновили нужное. И всё! Запустили сборку в другом режиме - и установили новинку.

- Планы и дальнейшие перспективы?
- Дальнейшие планы: собрать обьёмную сборку бессплатных программ. Ячеек, содержащих такие программы несколько сотен! Необходимо коррекция, проверка.
Еще планы: создание универсального сборника с 3-й фазой.
Создание профилированных сборников (только графических или только для восстановления информации, оффисная сборка)

- Ничего не понял как работать со сборником. Поясните на пальцах, как начать работу?
- Сборник писался для таких простых, неискушенных пользователей. Работа со сборником реализована в виде интегратора (start.exe). И вся работа пользователя - это нажатие нужных кнопок ..

Для начала работы со сборником запустите интегратор (start.exe), можете нажать кнопку Помощь - почитайте более развёрнутое описание.

Начните работу со сборником:
- во первых, его надо заполнить. Если вы работаете со сборником первый раз - он пустой! В нём нет инсталляторов. Сейчас мы будем его заполнять.
- Нажмите кнопку Create Pack. Запустится служебный файл create-pack.exe.
- Создайте профиль для обновления (кнопка UPdate-Pack)
- Пойдет работа скрипта для создания профиля (окно CMD в левом верхнем углу монитора) - не прерывайте работу его!
- После создания профиля обновления запустите MInstAll (для этого закройте окно Create Pack) и нажмите кнопку MInstAll в интеграторе.
- Запустится автоустановщик программ MInstall в режиме обновления. Помечайте нужные программы (можно все), нажимайте кнопку Выполнить. Пойдет обновление помеченных программ.
- Обновление идет последовательно, построчно на отмеченных программах. Будет мелькать окно CMD в левом верхнем углу. В окне можно проследить проценты выполнения задачи - обновления.
- Если пометили много программ, то время обновления всех помеченных ячеек может быть очень длительным. Полное заполнение всех ячеек в исходной (высушенной) сборки может занимать 1-2 часа.
- Заполнили сборник (можно выбирать для обновления любое количество программ, если у вас уже есть файлы, то обновление, вернее скачивание будет только тогда, когда эти обновления есть), закройте автоустановщик программ MInstall.
- После обновления ячеек, необходимо перестроить сборку для установки: Нажмите кнопку Create Pack. Запустится служебный файл create-pack.exe.
- Создайте профиль для Установки (кнопка Install-Pack)
- Пойдет запуск скрипта (создание профиля для установки) - так же не прерывайте работу его.
- После окончания работы скрипта, закройте окно Create Pack и в интеграторе запустите автоустановщик программ MInstall (по умолчанию он запустится с профилем обновления)
- Работайте в автоустановщике программ MInstall также, как и в режиме обновления. Помечайте галочками нужные программы и устанавливайте их.

Если не делаете обновления - то перестраивание профилей (фазирование) не нужно! Ибо нет обновлений - нет изменений в ячейках, нет изменений в профилях!
Обновили программы (а для пользователя неизвестно, обновилась ли помеченная ячека, если не наблюдать сам процесс обновления) - перестройте профили (перефазируйте сборку).
Новинки (новые, свежие, только что скачанные инсталляторы) никак не выделяются, время последнего успешного обновления будет новое, версия будет новая. Но это и не важно! Важно: если вышли новые версии на официальных сайтах - то они будут скачаны (если вы их пометили для обновления и скачали).

Вы сами следите за свежестью сборника. Есть возможность обновления - обновитесь. Нет возможности - пользуйтесь существующими в сборке инсталляторами.

Спасибо:
- большинство инсталляторов брал из официальных источников (офсайтов). Спасибо разработчикам за такие разные программы.
- описание (а это очень важно, ведь из многостраничного описания надо вырезать часть и уложить в одну строку и еще соблюсти размер (до 900 символов))
большинство описаний брал из:
а также не гнушался воровать описания у тутошных релизеров.
Спасибо им за это. Ёмкое, краткое полнофункциональное описание - это четверть затраченного времени.
 
Верх